home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1999 May: Tool Chest / Developer CD Series Tool Chest (Apple Computer)(May 1999).iso / Tool Chest / Networking / MacTCP / MacTCP Developer Tools / 802 LAP / LAPloopback.a < prev    next >
Encoding:
Text File  |  1993-06-15  |  3.1 KB  |  120 lines  |  [TEXT/MPS ]
  1. ;********************************************************************
  2. ;   (c) Copyright 1990-91 by Apple Computer, Inc.  All rights reserved.
  3. ;
  4. ;    LAPloopBack.a implements a software loopback function for IP
  5. ;********************************************************************
  6.  
  7.     TITLE    'LAPloopBack'
  8.     CASE    OBJECT
  9.  
  10. ;
  11. ;    1.2        11/29/90 Rajesh - modified for IEEE 802.3 LAP
  12. ;
  13.  
  14.         INCLUDE        'SysErr.a'
  15.         INCLUDE        'SysEqu.a'
  16.         INCLUDE        'ToolEqu.a'
  17.         INCLUDE        'Traps.a'
  18.  
  19.         IMPORT    Lap802_read_ph
  20.  
  21. LAPHeaderSize    EQU        22
  22. SCCLockout        EQU        $2600
  23.  
  24. ;
  25. ; TLoopBack(wds)
  26. ; struct wdsEntry *wds;
  27. ; 
  28. ; Implements the loopback function for IP.  When control returns to caller,
  29. ; the packet has been processed by the input side.  Caller responsible for 
  30. ; doing output IO completion
  31. ;
  32. TLoopBack    PROC    EXPORT
  33. ;
  34. ; handle loop-backs by setting up the registers to look like the 
  35. ; Lap802_read_ph was called by the driver
  36.        
  37.         movem.l    a2-a4,-(sp)
  38. ARG1    SET    3*4+4                        ;&IPB->laphdr
  39.         move.l    ARG1(sp),a0                ;Get pointer to ipb's 1st WDS
  40. ;
  41. ; A0 - pointer to current WDS entry */
  42. ; A1 - number of bytes left in current WDS entry */
  43. ; A2 - pointer to next byte to copy */
  44. ; A3 - pointer to first byte past IEEE 802.3 header */
  45. ; A4 - pointer to CopyPacket */
  46. ;
  47. ;        pea        #'TLoopBack'
  48. ;        _DebugStr
  49.         
  50.         move.l    2(a0),a3                ;Get Pointer to IEEE 802.3 header
  51.         add.l    #LAPHeaderSize,a3        ;Point past start of header, header
  52.                                         ;size = 22 bytes - RAJESH NOV 20,1990
  53.         add.l    #6,a0                    ;advance to next WDS
  54. ;        
  55. ; compute remaining length of packet
  56. ;
  57.         move.l    a0,-(sp)                ;save WDS pointer
  58.         clr.l    d1
  59. @1        add.w    (a0),d1                    ;add in length of this WDS entry
  60.         add.l    #6,a0                    ;advance to next WDS
  61.         move.w    (a0),d0
  62.         bne.s    @1                        ;if not end of WDS, loop
  63.         move.l    (sp)+,a0
  64.         
  65.         move.w    (a0),a1                    ;Get length of entry
  66.         move.l    2(a0),a2                ;and pointer to its data
  67.         lea.l    CopyPacket, a4            ;Get addr of copy routine
  68.         move.w    sr,-(sp)                ;Save current interrupt status
  69.         move.w    #SCCLockout,sr            ;and disable interrupts
  70.         jsr        Lap802_read_ph            ;call IEEE 802.3 packet read handler
  71.         move.w     (sp)+,sr                ;replace status register
  72.         movem.l    (sp)+,a2-a4
  73.         rts
  74.  
  75.  
  76.  
  77. CopyPacket    bra.s    Cpkt
  78.  
  79. CopyRest
  80. ;
  81. ; transfer the remaining bytes in the looped WDS to the input buffer
  82. ;
  83. ; A3 - input buffer pointer
  84. ; D3 - size of buffer
  85. ;
  86. ; A0 - pointer to current WDS entry */
  87. ; A1 - number of bytes left in current WDS entry */
  88. ; A2 - pointer to next byte to copy */
  89. ; A3 - pointer to first byte past IEEE 802.3 header */
  90. ; A4 - pointer to CopyPacket */
  91. ;
  92. Cpkt
  93. ;        pea        #'Cpkt'
  94. ;        _DebugStr
  95.         tst        d3                    ;zero requested size
  96.         beq.s    @3                    ;if so, complete immediately
  97.         move.w    a1,d0
  98.         beq.s    @3
  99. @1        move.b    (a2)+,(a3)+            ;transfer one byte
  100.         sub.w    #1,d3                ;decrement input buffer length
  101.         sub.w    #1,a1                ;decrement current wds length
  102.         move.w    a1,d0
  103.         bne.s    @2                    ;if not finished with this wds, skip
  104. ;
  105. ; advance to next WDS entry
  106. ;
  107.         add.l    #6,a0                ;point to next WDS entry
  108.         move.w    (a0), a1            ;get its length
  109.         move.w    a1,d0
  110.         beq.s    @3                    ;if zero, copy is finished
  111.         move.l    2(a0), a2            ;and get buffer pointer
  112.  
  113. @2        tst.w    d3                    ;decrement input buffer length
  114.         bne.s    @1                    ;if room left, loop
  115. @3        move.w  d3,d0
  116.         rts    
  117.     
  118.         ENDPROC
  119.         END    
  120.